廊下通行量カウンター

// human_traffic_counter_auto.ino

// to use time(), localtime()
#include <Time.h>
#define SGT 3600*8

// ESP8266
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h>

// 7 seg on I2C
#include <Wire.h>
#include "Adafruit_LEDBackpack.h"
#include "Adafruit_GFX.h" // for LED backpack

// json
#include <ArduinoJson.h>

// vars
// LED backpack
Adafruit_7segment LED_board = Adafruit_7segment();

// to connect wifi AP
char ssid[] = "your ap name";
char pass[] = "key for connection";

// pins
const int pirPin = 12; // signal from PIR

// status monitor vars
int pirState = LOW;
int val = LOW;
int ht_count = 0;
int ht_reported = 0;

// set time to send traffic count
  int H = 23;
  int M = 59;


/*
 * ========== setup ==========
*/
void setup() {
  // serial is only for debugging
  Serial.begin(9600);

  // pin modes
  pinMode(pirPin, INPUT);

  /////  [ESP8266 wifi]  /////
  WiFi.begin(ssid, pass);
  while(WiFi.status() != WL_CONNECTED){
    delay(500);
    Serial.println(".");
  }
  Serial.println("WiFi connnected to AP.");
  
  // I2C
  Wire.begin(4,5); // SDA, SCL
  // LED backpack
  LED_board.begin(0x70); // red
  LED_board.setBrightness(2);

  // internet time
  configTime( SGT, 0, "ntp.nict.jp", "sg.pool.ntp.org"); 
}


/*
 * ========== loop ==========
*/
void loop() {
  val = digitalRead(pirPin);    // read input value
  if (val == HIGH) {            // check if the input is HIGH
    if (pirState == LOW) {
      ht_count ++;
      Serial.print("Motion detected!  ");
      Serial.println(ht_count);
      pirState = HIGH;
    }
  } else {
    if (pirState == HIGH){
      Serial.println("Motion ended!");
      pirState = LOW;
    }
  }

  time_t t;
  struct tm *tm;
  static const char *wd[7] = {"Sun","Mon","Tue","Wed","Thr","Fri","Sat"};

  t = time(NULL);
  tm = localtime(&t);
  // this is to check if time is correctly set
  Serial.printf(" %04d/%02d/%02d(%s) %02d:%02d:%02d\n",
        tm->tm_year+1900, tm->tm_mon+1, tm->tm_mday,
        wd[tm->tm_wday],
        tm->tm_hour, tm->tm_min, tm->tm_sec);
  
  if ((tm->tm_hour == H) and (tm->tm_min == M)) {
    if (ht_reported == 0) {
      // send ht_count to raspi
      sendToRaspi(ht_count);
      // set it to reported
      ht_reported = 1;
      // display 8888
      ht_count = 8888;
      updateLED(ht_count);
    }
  }

  // update LED
  updateLED(ht_count);
  delay(100);
}


/*
 *  ========== functions ==========
 */
void sendToRaspi(int count){
  DynamicJsonDocument doc(100);  // v6
  doc["traffic"] = count;  // v6

  if (WiFi.status() == WL_CONNECTED){
    HTTPClient http;

    http.begin("http://<ip address of 3B1>/toslack");
    http.addHeader("Content-Type", "application/json");

    String json_data;
    serializeJson(doc, json_data);  // v6

    int httpCode = http.POST(json_data);
    String payload = http.getString();

    Serial.println("#++++++++++++++++++++++#"); //--------(1)
    Serial.print("httpCode: ");
    Serial.println(httpCode); //Print HTTP return code
    Serial.print("payload ");
    Serial.println(payload); // Print request response payload
    Serial.println("#++++++++++++++++++++++#\n"); //------(1)

    http.end();
  }
}

void updateLED(int count)
{
  // update LED display
  LED_board.print(count);
  LED_board.writeDisplay();
}

# receive json from ESP8266 (human traffic counter),
# write a log then
# post slack

from flask import Flask, abort, request
import requests
import json
import datetime


def timestamp():
    # returns time stamp
    dt = datetime.datetime.now()
    ts = dt.strftime('%d%b%Y-%H:%M:%S')
    return ts


webhook_url = 'https://hooks.slack.com/services/'
webhook_url += 'your slack key'

app = Flask(__name__)


@app.route('/toslack', methods=['POST'])
def foo():
    print("\n=== POST received! ===")
    print("request.json is shown below.")
    print(request.json)

    if not request.json:
        abort(400)
    else:
        if "traffic" in request.json:  # from human traffic counter
            sendToSlack2(request.json)
            write_log2(request.json)

    return json.dumps(request.json)


def sendToSlack2(json_in_dict):
    print("sendToSlack2() called.")

    msg = "Human Traffic Counter\n"
    msg += "Report time: " + timestamp() + '\n'
    msg += 'Count: ' + str(json_in_dict['traffic']) + "\n"
    msg += ':1234: :walking: :woman-walking: :woman-walking: :man-walking:'

    slack_data = {'text': msg}
    response = requests.post(
        webhook_url, data=json.dumps(slack_data),
        headers={'Content-Type': 'application/json'}
    )

    print('response: ', response)

    if response.status_code != 200:
        print('### Request to slack returned an error: ', response.status_code)
        print('### Response text: ', response.text)


log_file2 = './humanTraffic_log.txt'


def write_log2(json_in_dict):
    data = [timestamp()]
    data.append(str(json_in_dict['traffic']))
    data_line = '\t'.join(data)
    # append data_line to the log file
    with open(log_file2, mode='a') as log:
        log.write(data_line + '\n')


if __name__ == '__main__':
    app.run(host='0.0.0.0', port=<ser your port here>, debug=True)